function Shunpo_Conditions takes nothing returns boolean   
     return GetSpellAbilityId() == 'A000'     
endfunction   

function Shunpo_Loop takes nothing returns nothing   
     local timer t = GetExpiredTimer()   
     local integer hid = GetHandleId(t)
     local unit UnitCaster = LoadUnitHandle(udg_Hash,hid,1)   
     local real Angle = LoadReal(udg_Hash,hid,2)
     local real Speed = LoadReal(udg_Hash,hid,3)
     local real Root = LoadReal(udg_Hash,hid,4)
     local real Range = LoadReal(udg_Hash,hid,5)
     local real x1 = GetUnitX(UnitCaster)  
     local real y1 = GetUnitY(UnitCaster)  
     local real x3 = x1 + Speed * Cos(Angle)
     local real y3 = y1 + Speed * Sin(Angle)
          
     call SetUnitX(UnitCaster,x3)
     call SetUnitY(UnitCaster,y3)
      
     call SaveReal(udg_Hash,hid,5,Range+Speed)
          
     if Root <= Range then
         call FlushChildHashtable(udg_Hash,hid)
         call PauseTimer(t)
         call DestroyTimer(t)
         call PauseUnit(UnitCaster,false)
         call SetUnitVertexColor(UnitCaster,255,255,255,255)
         call SetUnitPathing(UnitCaster,true)
     endif
          
        set t = null
        set UnitCaster = null
endfunction     

function Shunpo_Actions takes nothing returns nothing          
     local unit UnitCaster = GetTriggerUnit()
     local real x1 = GetUnitX(UnitCaster)   
     local real y1 = GetUnitY(UnitCaster)   
     local real x2 = GetSpellTargetX()   
     local real y2 = GetSpellTargetY()  
     local real Angle = Atan2(y2 - y1, x2 - x1)   
     local real Speed = 30.
     local real Root = SquareRoot((x1-x2) * (x1-x2) + (y1-y2) * (y1-y2))
     local real Range = 0.
     local real Interval = .005
     local timer t = CreateTimer()     
     local integer hid = GetHandleId(t)
         
     call PauseUnit(UnitCaster,true)
     call SetUnitVertexColor(UnitCaster,25,25,25,75)
     call SetUnitPathing(UnitCaster,false)
          
     call SaveUnitHandle(udg_Hash,hid,1,UnitCaster)
     call SaveReal(udg_Hash,hid,2,Angle)
     call SaveReal(udg_Hash,hid,3,Speed)
     call SaveReal(udg_Hash,hid,4,Root)
     call SaveReal(udg_Hash,hid,5,Range)
          
     call TimerStart(t,Interval,true,function Shunpo_Loop)   
            
     set t = null   
     set UnitCaster = null   
endfunction   

function InitTrig_Shunpo takes nothing returns nothing   
     set gg_trg_Shunpo = CreateTrigger()   
     call TriggerRegisterAnyUnitEventBJ(gg_trg_Shunpo,EVENT_PLAYER_UNIT_SPELL_EFFECT)  
     call TriggerAddCondition(gg_trg_Shunpo,Condition(function Shunpo_Conditions))   
     call TriggerAddAction(gg_trg_Shunpo,function Shunpo_Actions)   
endfunction