function MeleeStartingUnitsConvertHuman takes player whichPlayer, location startLoc, boolean doHeroes, boolean doCamera, boolean doPreload returns nothing
     local boolean  useRandomHero = IsMapFlagSet(MAP_RANDOM_HERO)
     local real     unitSpacing   = 64.00
     local unit     nearestMine
     local location nearMineLoc
     local location heroLoc
     local real     peonX
     local real     peonY
     local unit     townHall = null

     if (doPreload) then
         call Preloader( "scripts\\HumanMelee.pld" )
     endif

     set nearestMine = MeleeFindNearestMine(startLoc, bj_MELEE_MINE_SEARCH_RADIUS)
     if (nearestMine != null) then
         set townHall = CreateUnitAtLoc(whichPlayer, 'htow', startLoc, bj_UNIT_FACING)
          
         set nearMineLoc = MeleeGetProjectedLoc(GetUnitLoc(nearestMine), startLoc, 320, 0)
         set peonX = GetLocationX(nearMineLoc)
         set peonY = GetLocationY(nearMineLoc)
         call CreateUnit(whichPlayer, 'hpea', peonX + 0.00 * unitSpacing, peonY + 1.00 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX + 1.00 * unitSpacing, peonY + 0.15 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX - 1.00 * unitSpacing, peonY + 0.15 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX + 0.60 * unitSpacing, peonY - 1.00 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX - 0.60 * unitSpacing, peonY - 1.00 * unitSpacing, bj_UNIT_FACING)

         set heroLoc = MeleeGetProjectedLoc(GetUnitLoc(nearestMine), startLoc, 384, 45)
     else
         set townHall = CreateUnitAtLoc(whichPlayer, 'htow', startLoc, bj_UNIT_FACING)
          
         set peonX = GetLocationX(startLoc)
         set peonY = GetLocationY(startLoc) - 224.00
         call CreateUnit(whichPlayer, 'hpea', peonX + 2.00 * unitSpacing, peonY + 0.00 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX + 1.00 * unitSpacing, peonY + 0.00 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX + 0.00 * unitSpacing, peonY + 0.00 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX - 1.00 * unitSpacing, peonY + 0.00 * unitSpacing, bj_UNIT_FACING)
         call CreateUnit(whichPlayer, 'hpea', peonX - 2.00 * unitSpacing, peonY + 0.00 * unitSpacing, bj_UNIT_FACING)

         set heroLoc = Location(peonX, peonY - 2.00 * unitSpacing)
     endif

     if (townHall != null) then
         call UnitAddAbilityBJ('Amic', townHall)
         call UnitMakeAbilityPermanentBJ(true, 'Amic', townHall)
     endif

     if (doHeroes) then
         if useRandomHero then
             call MeleeRandomHeroLoc(whichPlayer, 'Hamg', 'Hmkg', 'Hpal', 'Hblm', heroLoc)
         else
             call SetPlayerState(whichPlayer, PLAYER_STATE_RESOURCE_HERO_TOKENS, bj_MELEE_STARTING_HERO_TOKENS)
         endif
     endif

     if (doCamera) then
         call SetCameraPositionForPlayer(whichPlayer, peonX, peonY)
         call SetCameraQuickPositionForPlayer(whichPlayer, peonX, peonY)
     endif
endfunction

function MeleeStartingUnitsCustom takes nothing returns nothing
     local integer  index
     local player   indexPlayer
     local location indexStartLoc
     local race     indexRace

     call Preloader( "scripts\\SharedMelee.pld" )

     set index = 0
     loop
         set indexPlayer = Player(index)
         if (GetPlayerSlotState(indexPlayer) == PLAYER_SLOT_STATE_PLAYING) then
             set indexStartLoc = GetStartLocationLoc(GetPlayerStartLocation(indexPlayer))
             set indexRace = GetPlayerRace(indexPlayer)

             if (indexRace == RACE_HUMAN) then
                 call MeleeStartingUnitsHuman(indexPlayer, indexStartLoc, true, true, true)
             elseif (indexRace == RACE_ORC) then
                 call MeleeStartingUnitsOrc(indexPlayer, indexStartLoc, true, true, true)
             elseif (indexRace == RACE_UNDEAD) then
                 call MeleeStartingUnitsUndead(indexPlayer, indexStartLoc, true, true, true)
             elseif (indexRace == RACE_NIGHTELF) then
                 call MeleeStartingUnitsConvertHuman(indexPlayer, indexStartLoc, true, true, true)
             else
                 call MeleeStartingUnitsUnknownRace(indexPlayer, indexStartLoc, true, true, true)
             endif
         endif

         set index = index + 1
         exitwhen index == bj_MAX_PLAYERS
     endloop
      
endfunction

function Trig_Melee_Initialization_Actions takes nothing returns nothing
     local integer i = 0
     set udg_Hash=InitHashtable()
     call MeleeStartingVisibility(  )
     call MeleeStartingHeroLimit(  )
     call MeleeGrantHeroItems(  )
     call MeleeStartingResources(  )
     call MeleeClearExcessUnits(  )
     call MeleeStartingAI(  )
     call MeleeInitVictoryDefeat(  )
     call MeleeStartingUnitsCustom()

     loop
       exitwhen i > 7
         if GetPlayerRace( Player(i) ) == RACE_NIGHTELF then
             call SetPlayerRacePreference( Player(i), RACE_PREF_HUMAN )
         endif
         set i = i + 1
       endloop
endfunction

//===========================================================================
function InitTrig_Melee_Initialization takes nothing returns nothing
     set gg_trg_Melee_Initialization = CreateTrigger(  )
     call TriggerAddAction( gg_trg_Melee_Initialization, function Trig_Melee_Initialization_Actions )
endfunction