//globals
    //constant group udg_G = CreateGroup()
//endglobals

constant function BattleOrder_Spell takes nothing returns integer
    return 'A0BE'
endfunction

constant function BattleOrder_Ability takes nothing returns integer
    return 'A04T'
endfunction

constant function BattleOrder_DummyId takes nothing returns integer
    return 'hkni'
endfunction

constant function BattleOrder_Effect takes nothing returns string
    return "war3mapImported\\BattleCryCaster.mdx"
endfunction

constant function BattleOrder_LoopEffect takes nothing returns string
    return "Abilities\\Spells\\Human\\ThunderClap\\ThunderClapCaster.mdl"
endfunction

constant function BattleOrder_Range takes nothing returns real
    return 200.
endfunction

constant function BattleOrder_Tacts takes nothing returns integer
    return 30
endfunction

constant function BattleOrder_Period takes nothing returns real
    return 1.
endfunction

constant function BattleOrder_Delay takes nothing returns real
    return .3
endfunction

function BattleOrder_Damage takes integer n returns real
    //1 => 10
    //2 => 11.5
    //3 => 13.5
    //4 => 16
    //etc
    local real d = (n - 1) * .5
    return d * (2.5 + d) + 10.
endfunction

function Trig_Battle_Orders_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == BattleOrder_Spell()
endfunction

function SeismicDamagingFilter takes nothing returns boolean
    return GetOwningPlayer(GetFilterUnit()) != Player(PLAYER_NEUTRAL_PASSIVE) and GetWidgetLife(GetFilterUnit()) > .405 and IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false
endfunction

function BOLooping takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit u = LoadUnitHandle(udg_Hash, id, 0)
    local unit ud = LoadUnitHandle(udg_Hash, id, 1)
    local integer c = LoadInteger(udg_Hash, id, 2)
    local real d = LoadReal(udg_Hash, id, 3)
    local unit uc
    local player p1 = GetOwningPlayer(u)
    local player p2
    local real x = GetWidgetX(u)
    local real y = GetWidgetY(u)
    call SetUnitPosition(ud, x, y)
    call GroupEnumUnitsInRange(udg_G, x, y, BattleOrder_Range(), Filter(function SeismicDamagingFilter))
    loop
        set uc = FirstOfGroup(udg_G)
        exitwhen uc == null
        call GroupRemoveUnit(udg_G, uc)
        set p2 = GetOwningPlayer(uc)
        if p2 != p1 and IsPlayerEnemy(p1, p2) then
            call UnitDamageTarget(ud, uc, d, true, false, ATTACK_TYPE_MAGIC, DAMAGE_TYPE_FORCE, null)
        endif
    endloop
    call DestroyEffect(AddSpecialEffectTarget(BattleOrder_LoopEffect(), u, "origin"))
    call SaveInteger(udg_Hash, id, 2, c + 1)
    if c > BattleOrder_Tacts() or GetWidgetLife(u) <= .405 then
        call UnitRemoveAbility(u, BattleOrder_Ability())
        call RemoveUnit(ud)
        call PauseTimer(t)
        call DestroyTimer(t)
        call FlushChildHashtable(udg_Hash, id)
    endif
    set t = null
    set ud = null
    set u = null
    set p1 = null
    set p2 = null
endfunction

function BOBuff takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit u = LoadUnitHandle(udg_Hash, id, 0)
    local unit ud = CreateUnit(GetOwningPlayer(u), BattleOrder_DummyId(), GetWidgetX(u), GetWidgetY(u), .0)
    call DestroyEffect(AddSpecialEffectTarget(BattleOrder_Effect(), u, "origin"))
    call UnitAddAbility(u, BattleOrder_Ability())
    call SaveAgentHandle(udg_Hash, id, 1, ud)
    call SaveInteger(udg_Hash, id, 2, 1)
    call TimerStart(t, BattleOrder_Period(), true, function BOLooping)
    set t = null
    set u = null
    set ud = null
endfunction

function Trig_Battle_Orders_Actions takes nothing returns nothing
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    local unit u = GetTriggerUnit()
    local integer l = GetUnitAbilityLevel(u, BattleOrder_Spell())
    call SaveAgentHandle(udg_Hash, id, 0, u)
    call SaveReal(udg_Hash, id, 3, BattleOrder_Damage(l))
    call TimerStart(t, BattleOrder_Delay(), false, function BOBuff)
    set t = null
    set u = null
endfunction

function InitTrig_Battle_Orders takes nothing returns nothing
    local trigger t = CreateTrigger()
    local unit u = CreateUnit(Player(15), BattleOrder_DummyId(), .0, .0, .0)
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t, Condition(function Trig_Battle_Orders_Conditions))
    call TriggerAddAction(t, function Trig_Battle_Orders_Actions)
    call Preload(BattleOrder_Effect())
    call Preload(BattleOrder_LoopEffect())
    call UnitAddAbility(u, BattleOrder_Ability())
    call RemoveUnit(u)
    set t = null
    set u = null
endfunction

function fact takes integer n returns integer
    local integer result = 1
    loop
        exitwhen n <= 1
        set result = result * n
        set n = n - 1
    endloop
    return result
endfunction

function fact_rcsv takes integer n returns integer
    if n <= 1 then
        return 1
    endif
    return n * fact_rcsv(n - 1)
endfunction