library NumberKeyEvent initializer init uses Table

// Configurations
globals
// Hot key dummy's raw code in OE
private constant integer DUMMY_ID = 'h000'

// Location of dummy, better to be an invisible spot
// in your map
private constant real DUMMY_X = 2521.32
private constant real DUMMY_Y = -2827.15

// Delay after calibration to activate the event
private constant real ACTIVE_DELAY = 0.25

endglobals

/*******************************************************
*
* NumberKeyEvent v1.1
* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*
* Description
* ¯¯¯¯¯¯¯¯¯¯¯
* Allows you to do actions when a player presses
* any number key (0-9)
*
*
* Cons
* ¯¯¯¯
* - Needs calibration (check demo)
* - Disturbs unit selection
*
*
* Requires
* ¯¯¯¯¯¯¯¯
* - Table by Bribe | hiveworkshop.com/forums/jass-resources-412/snippet-new-table-188084/
*
*
* How to import
* ¯¯¯¯¯¯¯¯¯¯¯¯¯
* - Copy dummy unit from object editor to your map
* - Copy the trigger folder to your map
* - Configure the system properly
*
*
* API
* ¯¯¯
* function CalibrateKeys takes integer playerId returns nothing
*
* function RegisterAnyNumberKeyEvent takes boolexpr func returns triggercondition
*
* function UnregisterAnyNumberKeyEvent takes triggercondition tc returns nothing
*
* function GetPressedNumberKey takes nothing returns integer
*
* function GetPressingPlayer takes nothing returns player
*
*
* Notes
* ¯¯¯¯¯
* - Better to preserve an invisible area for dummy
* units to avoid unwanted camera panning
* - You will surely need some work around in adapting
* the system to your map
* - Player must press CTRL when CalibrateKeys function
* is called
* - You must allow players to calibrate their keys
* anytime whenever they want, in case the calibration
* is failed, since there is no "fast" way to validate
* the calibration (perhaps not yet)
*
*
********************************************************/

globals
private unit array KeyUnit
private boolean array IsCalibrated
private boolean array IsRegistered
private timer array DelayTimer
private trigger Handler = CreateTrigger()
private integer EventPressed
private player EventPresser
private Table Ht
endglobals

private function onSelection takes nothing returns boolean

local unit u = GetTriggerUnit()
local player p = GetOwningPlayer(u)
local integer id = GetPlayerId(p)

if GetLocalPlayer() == p then
call ClearSelection()
endif
if IsCalibrated[id] then
set EventPresser = p
set EventPressed = Ht.integer[GetHandleId(u)]
call TriggerEvaluate(Handler)
set EventPressed = 0
set EventPresser = null
endif
set u = null

return false
endfunction

private function activate takes nothing returns nothing
set IsCalibrated[Ht.integer[GetHandleId(GetExpiredTimer())]] = true
endfunction

function CalibrateKeys takes integer playerId returns nothing

local integer i

if IsRegistered[playerId] then
set IsCalibrated[playerId] = false
if GetLocalPlayer() == Player(playerId) then
set i = 0
loop
exitwhen i > 9
call ClearSelection()
call SelectUnit(KeyUnit[playerId*0xA+i], true)
call ForceUIKey(I2S(i))
set i = i + 1
endloop
call ClearSelection()
endif
call TimerStart(DelayTimer[playerId], ACTIVE_DELAY, false, function activate)
endif

endfunction

function GetPressedNumberKey takes nothing returns integer
return EventPressed
endfunction

function GetPressingPlayer takes nothing returns player
return EventPresser
endfunction

function RegisterAnyNumberKeyEvent takes boolexpr func returns triggercondition
return TriggerAddCondition(Handler, func)
endfunction

function UnregisterAnyNumberKeyEvent takes triggercondition tc returns nothing
call TriggerRemoveCondition(Handler, tc)
endfunction

private function init takes nothing returns nothing

local trigger t = CreateTrigger()
local integer i = 0
local integer j
local integer k
local player p

set Ht = Table.create()
call TriggerAddCondition(t, Condition(function onSelection))
loop
exitwhen i > 11
set p = Player(i)
set IsRegistered[i] = GetPlayerController(p) == MAP_CONTROL_USER and GetPlayerSlotState(p) == PLAYER_SLOT_STATE_PLAYING
if IsRegistered[i] then
set DelayTimer[i] = CreateTimer()
set Ht.integer[GetHandleId(DelayTimer[i])] = i
set j = 0
loop
exitwhen j > 9
set k = i*0xA+j
set KeyUnit[k] = CreateUnit(p, DUMMY_ID, DUMMY_X, DUMMY_Y, 0)
call TriggerRegisterUnitEvent(t, KeyUnit[k], EVENT_UNIT_SELECTED)
set Ht.integer[GetHandleId(KeyUnit[k])] = j
call PauseUnit(KeyUnit[k], true)
set j = j + 1
endloop
endif
set i = i + 1
endloop

endfunction

endlibrary