function Trig_Pistol_Conditions takes nothing returns boolean
     return GetSpellAbilityId() == 'A000'
endfunction

function Trig_Pistol_Check takes nothing returns boolean
     return IsUnitEnemy(GetFilterUnit(), Player(1))
endfunction

function Trig_Pistol_Move takes nothing returns nothing
     local timer t = GetExpiredTimer()
     local unit u = LoadUnitHandle(udg_HashTable, GetHandleId(t), 1)
     local integer i = LoadInteger(udg_HashTable, GetHandleId(t), 1)
     local unit shooter = LoadUnitHandle(udg_HashTable, GetHandleId(t), 2)
     local real x = GetUnitX(u)
     local real y = GetUnitY(u)
     local real f = GetUnitFacing(u)*.01745
     local group g = CreateGroup()
     local unit target = null
     call SetUnitPosition(u, x+10*Cos(f), y+10*Sin(f))
     call GroupEnumUnitsInRange(g, GetUnitX(u), GetUnitY(u), 100, Condition(function Trig_Pistol_Check))  
     set target = FirstOfGroup(g)
     if target != null then
         call UnitDamageTarget(u, target, 150-udg_Difficulty*5, true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_MAGIC, WEAPON_TYPE_WHOKNOWS)
         call KillUnit(u)
         call PauseTimer(t)
         call DestroyTimer(t)
         call GroupEnumUnitsInRange(g, GetUnitX(target), GetUnitY(target), 200+udg_Difficulty*100, Condition(function Trig_Pistol_Check))
         call GroupPointOrder(g, "attack", GetUnitX(shooter), GetUnitY(shooter))
         call FlushChildHashtable(udg_HashTable, GetHandleId(t))
     endif
     if i == 500 then
         call FlushChildHashtable(udg_HashTable, GetHandleId(t))
         call KillUnit(u)
         call PauseTimer(t)
         call DestroyTimer(t)
     else
         set i = i + 1
         call SaveInteger(udg_HashTable, GetHandleId(t), 1, i)
     endif
     set t = null
     set u = null
     set shooter = null
     set target = null
     call DestroyGroup(g)
     set g = null
endfunction

function Trig_Pistol_Actions takes nothing returns nothing
     local unit u = CreateUnit(GetOwningPlayer(GetSpellAbilityUnit()), 'hdhw', GetUnitX(GetSpellAbilityUnit()), GetUnitY(GetSpellAbilityUnit()), GetUnitFacing(GetSpellAbilityUnit()))
     local timer t = CreateTimer()
     call SaveUnitHandle(udg_HashTable, GetHandleId(t), 1, u)
     call SaveUnitHandle(udg_HashTable, GetHandleId(t), 2, GetSpellAbilityUnit())
     call SaveInteger(udg_HashTable, GetHandleId(t), 1, 1)
     call SetUnitPathing(u, false)
     call TimerStart(t, 0.01, true, function Trig_Pistol_Move)
     set u = null
     set t = null
endfunction

//===========================================================================
function InitTrig_Pistol takes nothing returns nothing
     set gg_trg_Pistol = CreateTrigger(  )
     call TriggerRegisterAnyUnitEventBJ( gg_trg_Pistol, EVENT_PLAYER_UNIT_SPELL_EFFECT )
     call TriggerAddCondition( gg_trg_Pistol, Condition( function Trig_Pistol_Conditions ) )
     call TriggerAddAction( gg_trg_Pistol, function Trig_Pistol_Actions )
endfunction