globals    
group              GDT = CreateGroup()
trigger            TDT = CreateTrigger()
endglobals

define {
SPELL      = 'AEev' //ид спела у героя
DUMMY      = 'n000' //ид дамми юнита
SPELL_D    = 'Aslo' //ид спела у дамми юнита
ORDER      = "slow" // приказ способности у дамми
CHANCE     = 12 //шанс
CHANCE_LVL = 3 // прирост шанса на уровень
DAMAGE     = 5 // дополнительный урон
DAMAGE_LVL = 5 //прирост урона на уровень
}

function Trig_DealingDamage_Conditions takes nothing returns boolean
       return GetUnitAbilityLevel(GetAttacker(),SPELL) > 0
endfunction

function BDealingDamage takes nothing returns nothing
local unit u=GetEventDamageSource()
local unit ut=GetTriggerUnit()
local unit d
local real dm=GetEventDamage()
local integer lvl=GetUnitAbilityLevel(u,SPELL)
if dm>0. and GetUnitAbilityLevel(u,SPELL)>0 then
       call DisableTrigger(GetTriggeringTrigger())
       call UnitDamageTarget(u,ut,DAMAGE+DAMAGE_LVL*lvl,true,false,ATTACK_TYPE_HERO,DAMAGE_TYPE_NORMAL,null)
       call EnableTrigger(GetTriggeringTrigger())
       if GetRandomInt(1,100)<=CHANCE+CHANCE_LVL*lvl then
              
           set d=CreateUnit(GetOwningPlayer(u),DUMMY,GetWidgetX(ut),GetWidgetY(ut),0.)
           call UnitApplyTimedLife(d,'BTLF',6.3)
           call UnitAddAbility(d,SPELL_D)
           call SetUnitAbilityLevel(d,SPELL_D,lvl)
           call IssueTargetOrder(d,ORDER,ut)
       endif
       call BJDebugMsg(I2S(R2I((GetEventDamage()))))
endif

set u=null
set ut=null
set d=null
endfunction

function Trig_DealingDamage_Actions takes nothing returns nothing
local unit u=GetTriggerUnit()
if IsUnitInGroup(u,GDT)==false then
       call TriggerRegisterUnitEvent(TDT,u,EVENT_UNIT_DAMAGED)
       call GroupAddUnit(GDT,u)
endif
set u=null
endfunction

//===========================================================================
function InitTrig_DealingDamage takes nothing returns nothing
       set gg_trg_DealingDamage=CreateTrigger()
       call TriggerRegisterAnyUnitEventBJ(gg_trg_DealingDamage,EVENT_PLAYER_UNIT_ATTACKED)
       call TriggerAddCondition(gg_trg_DealingDamage,Condition(function Trig_DealingDamage_Conditions))
       call TriggerAddAction(gg_trg_DealingDamage,function Trig_DealingDamage_Actions)
       call TriggerAddAction(TDT,function BDealingDamage)
endfunction

function DestroyPasSpell takes nothing returns nothing
     local trigger t = GetTriggeringTrigger()
     local unit c = LoadUnitHandle(udg_HashDMG,GetHandleId(t),1)
     local trigger d = LoadTriggerHandle(udg_HashDMG,GetHandleId(c),1)
     //унитчожаем триггер на получение урона
     call TriggerRemoveAction(d,LoadTriggerActionHandle(udg_HashDMG,GetHandleId(c),2))
     call TriggerRemoveCondition(d,LoadTriggerConditionHandle(udg_HashDMG,GetHandleId(c),3))
     call DestroyBoolExpr(LoadBooleanExprHandle(udg_HashDMG,GetHandleId(c),4))  
     call DestroyTrigger(d)
     //уничтожаем этот триггер
     call TriggerRemoveAction(t,LoadTriggerActionHandle(udg_HashDMG,GetHandleId(t),0))
     call DestroyTrigger(t)
     call FlushChildHashtable(udg_HashDMG, GetHandleId(t))
     call FlushChildHashtable(udg_HashDMG, GetHandleId(c))
     set t = null
     set c = null
     set d = null  
endfunction

//проверка на имение абилы, и расчет шанса
function PasSpell_Conditions takes nothing returns boolean
     return GetUnitAbilityLevel(GetEventDamageSource(), 'AHwe') > 0 and not(IsUnitType(GetTriggerUnit(), UNIT_TYPE_STRUCTURE)) and GetRandomInt(1,100)<=6+4*GetUnitAbilityLevel(GetEventDamageSource(), 'AHwe')
endfunction

//действия при выпадении шанса
function PasSpell_Actions takes nothing returns nothing
     local unit u = GetEventDamageSource()
     local unit c = GetTriggerUnit()
     local unit d = CreateUnit(GetOwningPlayer(u),'u000',GetUnitX(c),GetUnitY(c),0.)
     call UnitAddAbility(d,'A000')
     call IssueTargetOrder(d, "frostnova", c)
     call UnitApplyTimedLife(d, 'BTLF', 2.00)
     set u = null
     set c = null
     set d = null
endfunction

function UnitAttack takes nothing returns nothing
     local unit c = GetEventTargetUnit()
     local trigger t = null
     local triggeraction tra = null
     local triggercondition trc = null
     local boolexpr b = null
     if(not(LoadBoolean(udg_HashDMG,GetHandleId(c),0)))then
         //создаем триггер на получение урона
         set t = CreateTrigger()
         set tra = TriggerAddAction(t, function PasSpell_Actions)
         set b = Condition(function PasSpell_Conditions)
         set trc = TriggerAddCondition(t, b)
         call TriggerRegisterUnitEvent(t, c, EVENT_UNIT_DAMAGED)
         call SaveBoolean(udg_HashDMG,GetHandleId(c),0,true)
         call SaveTriggerHandle(udg_HashDMG,GetHandleId(c),1,t)
         call SaveTriggerActionHandle(udg_HashDMG,GetHandleId(c),2,tra)
         call SaveTriggerConditionHandle(udg_HashDMG,GetHandleId(c),3,trc)
         call SaveBooleanExprHandle(udg_HashDMG,GetHandleId(c),4,b)
         //триггер на уничтожения трггера получения урона при смерти юнита
         set t = CreateTrigger()
         set tra = TriggerAddAction(t, function DestroyPasSpell)
         call TriggerRegisterUnitEvent(t, c, EVENT_UNIT_DEATH)
         call SaveTriggerActionHandle(udg_HashDMG,GetHandleId(t),0,tra)
         call SaveUnitHandle(udg_HashDMG,GetHandleId(t),1,c)  
         set t = null
         set tra = null
         set trc = null
         set b = null
     endif
     set c = null
endfunction

//проверка на прокачиваемую абилу
function Trig_LearningSkill_Conditions takes nothing returns boolean
    return GetLearnedSkill() == 'AHwe' and GetUnitAbilityLevel(GetLearningUnit(),'AHwe')==1
endfunction

//создаем новый триггер, конкретно на нашего юнита
function Trig_LearningSkill_Actions takes nothing returns nothing
     local trigger t = CreateTrigger()
     call TriggerRegisterUnitEvent( t, GetLearningUnit(), EVENT_UNIT_TARGET_IN_RANGE )
     call TriggerAddAction( t, function UnitAttack )
     set t = null  
endfunction

//===========================================================================
function InitTrig_LearningSkill takes nothing returns nothing
     set gg_trg_LearningSkill = CreateTrigger(  )
     call TriggerRegisterAnyUnitEventBJ( gg_trg_LearningSkill, EVENT_PLAYER_HERO_SKILL )
     call TriggerAddCondition( gg_trg_LearningSkill, Condition( function Trig_LearningSkill_Conditions ) )
     call TriggerAddAction( gg_trg_LearningSkill, function Trig_LearningSkill_Actions )
endfunction