//## Тряска камеры
function ShakeCamera_Child takes nothing returns nothing
local timer t = GetExpiredTimer()
local integer id = GetHandleId(t)
local real x = LoadReal(udg_golem,id,0)
local real y = LoadReal(udg_golem,id,1)
local real r = LoadReal(udg_golem,id,2)
local real d = LoadReal(udg_golem,id,3)
local real p = LoadReal(udg_golem,id,4)
local real m = LoadReal(udg_golem,id,5)
local real ccx = GetCameraTargetPositionX()
local real ccy = GetCameraTargetPositionY()
local real dens = m/r // Радиус от эпицентра - сегменты трясения.
call SaveReal(udg_golem,id,4,p+.04)
if p >= d then
call CameraSetSourceNoise(0,0)
call CameraSetTargetNoise(0,0)
call FlushChildHashtable(udg_golem,id)
call PauseTimer(t)
call DestroyTimer(t)
else
set m = SquareRoot((ccx-x)*(ccx-x)+(ccy-y)*(ccy-y))
// Если расстояние больше радиуса, то не трясти камеру.
if m >= r then
set m = 0
else
// Чем больше удаление, тем меньше магнитуда.
// изначальная магнитуда - расстояние * dens.
set m = LoadReal(udg_golem,id,5) - m * dens
endif
// Почему у каждого трясёт по разному?
// Потому что ccx и ccy - локальные данные. Так-то. <img rel="usm" src="http://warcraft3ft.info/image/smiles/smile.gif" border="0" align="absmiddle" alt=":)" />
call CameraSetTargetNoiseEx(m*2.,m*Pow(10,m),true)
call CameraSetSourceNoiseEx(m*2.,m*Pow(10,m),true)
// Магнитуду уменьшаем.
call SaveReal(udg_golem,id,5,LoadReal(udg_golem,id,5)-3/d)
endif
set t = null
endfunction
function ShakeCamera takes real x, real y, real shakeRadius, real duration returns nothing
local timer t = CreateTimer()
local integer id = GetHandleId(t)
call SaveReal(udg_golem,id,0,x)
call SaveReal(udg_golem,id,1,y)
call SaveReal(udg_golem,id,2,shakeRadius)
call SaveReal(udg_golem,id,3,duration)
call SaveReal(udg_golem,id,4,0.)
call SaveReal(udg_golem,id,5,40.) // Начальная магнитуда в эпицентре по Рихтеру.
call TimerStart(t,.04,true,function ShakeCamera_Child)
set t = null
endfunction
