[code=jass]library FICS {
#include "cj_types_priv.j"

#define {
private EFFECT = "Abilities\\Spells\\Items\\AIem\\AIemTarget.mdl"
private ATTACH = "origin"
private ITEM_MAP_SIZE = 8191
}

private constant timer T = CreateTimer();
private item Dropped[ ];
private int DropNum[ ], Temp[21];
private int DropCount = 0;
private int ItemMap[ITEM_MAP_SIZE];
private int Items[500][5], Recipes[256][8];
private int ItemCount = 0, RecipeCount = 0;
private int FirstList[ ], LastList[ ];
private int Recipe[ ], Next[ ], ListCount = 0;
private int CallbackArgument = 0;
private trigger Callbacks[500][2];
private bool Flag = true;

public int GetIndexById(int id) {
return ItemMap[id - 'I000'];
}

public int GetNormalByIndex(int index) {
return Items[index][0];
}

public int GetRuneByIndex(int index) {
return Items[index][1];
}

public int GetDisabledByIndex(int index) {
return Items[index][2];
}

public int GetGoldCostByIndex(int index) {
return Items[index][3];
}

public int GetLumberCostByIndex(int index) {
return Items[index][4];
}

public trigger GetPickupCallbackByIndex(int index) {
return Callbacks[index][0];
}

public trigger GetDropCallbackByIndex(int index) {
return Callbacks[index][1];
}

public int GetManipulatedItemIndex() {
return CallbackArgument;
}

public int Register(int id, int rune, int dis, int gcost, int lcost) {
ItemCount++;
static if DEBUG_MODE {
if id - 'I000' > ITEM_MAP_SIZE || rune - 'I000' > ITEM_MAP_SIZE || dis - 'I000' > ITEM_MAP_SIZE || id - 'I000' < 0 || rune - 'I000' < 0 || dis - 'I000' < 0 {
BJDebugMsg("|cffff0000CRITICAL ERROR in FICS: Too many items. Increase the ITEM_MAP_SIZE constant. This message also may be shown if you are trying to register a standard item. Use only custom items instead.|r");
return 0;
}
}
ItemMap[id - 'I000'] = ItemCount;
ItemMap[rune - 'I000'] = ItemCount;
ItemMap[dis - 'I000'] = ItemCount;
Items[ItemCount][0] = id;
Items[ItemCount][1] = rune;
Items[ItemCount][2] = dis;
Items[ItemCount][3] = gcost;
Items[ItemCount][4] = lcost;
return ItemCount;
}

public void SetCallbacks(int index, trigger pickup, trigger drop) {
Callbacks[index][0] = pickup;
Callbacks[index][1] = drop;
}

public void Register7(int result, int i0, int i1, int i2, int i3, int i4, int i5, int i6) {
static if DEBUG_MODE {
if result < 0 || result > ItemCount {
BJDebugMsg("|cffff0000CRITICAL ERROR in FICS: Invalid index in recipe.|r");
return;
}
}
#for j(0, 6)
Temp[j] = i##j;
static if DEBUG_MODE {
if i##j < 0 || i##j > ItemCount {
BJDebugMsg("|cffff0000CRITICAL ERROR in FICS: Invalid index in recipe.|r");
return;
}
}
#endfor
RecipeCount++;
//Записываем в Recipes сортированные по невозрастанию индексы.
for (int i = 0) {
if Temp[i] > 0 {
if Temp[i]:LastList == 0 || Temp[i]:LastList:Recipe != RecipeCount {
ListCount++;
if Temp[i]:LastList == 0 {
Temp[i]:FirstList = ListCount;
} else {
Temp[i]:LastList:Next = ListCount;
}
Temp[i]:LastList = ListCount;
Temp[i]:LastList:Recipe = RecipeCount;
Temp[i]:LastList:Next = 0;
}
int j = i;
whilenot j == 0 || Recipes[RecipeCount][j - 1] >= Temp[i] {
Recipes[RecipeCount][j] = Recipes[RecipeCount][j - 1];
j--;
}
Recipes[RecipeCount][j] = Temp[i];
}
exitwhen i == 6;
i++;
}
Recipes[RecipeCount][7] = result;
}

public void Register6(int result, int i0, int i1, int i2, int i3, int i4, int i5) {
Register7(result, i0, i1, i2, i3, i4, i5, 0);
}

public void Register5(int result, int i0, int i1, int i2, int i3, int i4) {
Register6(result, i0, i1, i2, i3, i4, 0);
}

public void Register4(int result, int i0, int i1, int i2, int i3) {
Register5(result, i0, i1, i2, i3, 0);
}

public void Register3(int result, int i0, int i1, int i2) {
Register4(result, i0, i1, i2, 0);
}

public void Register2(int result, int i0, int i1) {
Register3(result, i0, i1, 0);
}

//Бесполезная штука, в общем-то, но такое тоже возможно.
public void Register1(int result, int i0) {
Register2(result, i0, 0);
}

private void DropItem(item it, int num) {
DropCount:Dropped = it;
DropCount:DropNum = num;
if ++DropCount == 1 {
TimerStart(T, .0, false, \
lambda void() {
item it;
do {
DropCount--;
if GetItemTypeId(DropCount:Dropped) != 0 && !IsItemOwned(DropCount:Dropped) {
it = CreateItem(GetRuneByIndex(DropCount:DropNum), /*
*/ GetWidgetX(DropCount:Dropped), GetWidgetY(DropCount:Dropped));
if GetItemType(DropCount:Dropped) == ITEM_TYPE_CHARGED {
SetItemCharges(it, GetItemCharges(DropCount:Dropped));
}
SetItemPlayer(it, GetItemPlayer(DropCount:Dropped), false);
RemoveItem(DropCount:Dropped);
}
} whilenot DropCount == 0;
it = null;
}
);
}
}

private bool PickActions() {
unit u = GetTriggerUnit();
item it = GetManipulatedItem(), it2;
player p = GetOwningPlayer(u);
int itid = GetItemTypeId(it), num = GetIndexById(itid);
int ls = num:FirstList;
int m = 6;
bool norm = itid == GetNormalByIndex(num);
bool rune = itid == GetRuneByIndex(num);
bool dis = itid == GetDisabledByIndex(num);
if Flag && num != 0 {
//Заполняем массив отсортированными по невозрастанию индексами предметов в системе.
Temp[0] = num;
Temp[7] = -1;
for (int i = 0) {
it2 = UnitItemInSlot(u, i);
if it != it2 {
int k = GetItemTypeId(it2), l = GetIndexById(k);
int j = i + 1;
if k == 0 || l == 0 || k != GetNormalByIndex(l) {
m--;
l = 0;
} else {
whilenot j == 0 || Temp[j - 1] >= l {
Temp[j] = Temp[j - 1];
Temp[j + 7] = Temp[j + 6];
j--;
}
}
Temp[j] = l;
Temp[j + 7] = i;
}
exitwhen i == 5;
i++;
}
whilenot ls == 0 {
//Если Recipes является подпоследовательностью Temp, создать предмет.
int j = 0, k = 0;
whilenot Temp[j] < Recipes[ls:Recipe][k] {
if Temp[j] == Recipes[ls:Recipe][k] {
Temp[k + 14] = Temp[j + 7];
k++;
if k == 7 || Recipes[ls:Recipe][k] == 0 {
k += 14;
whilenot --k < 14 {
if Temp[k] != -1 { RemoveItem(UnitItemInSlot(u, Temp[k])); }
}
if !rune { RemoveItem(it); }
SetItemPlayer(UnitAddItemById(u, GetNormalByIndex(Recipes[ls:Recipe][7])), p, false);
DestroyEffect(AddSpecialEffectTarget(EFFECT, u, ATTACH));
return false;
}
}
exitwhen j == m;
j++;
}
ls = ls:Next;
}
Flag = false;
p = GetItemPlayer(it);
bool bought = p == Player(15);
bool own = bought || p == GetOwningPlayer(u) || GetNormalByIndex(num) == GetDisabledByIndex(num);
if own {
itid = GetNormalByIndex(num);
if bought { p = GetOwningPlayer(u); }
} else {
itid = GetDisabledByIndex(num);
}
int i = 0;
bool empty = false;
if GetItemType(it) == ITEM_TYPE_CHARGED {
int j = GetItemCharges(it);
do {
it2 = UnitItemInSlot(u, i);
if it != it2 {
ls = GetItemTypeId(it2);
if (ls == GetNormalByIndex(num) && own) || (ls == GetDisabledByIndex(num) && GetItemPlayer(it2) == p) {
if own {
CallbackArgument = num;
TriggerEvaluate(GetPickupCallbackByIndex(num));
}
SetItemCharges(it2, GetItemCharges(it2) + j);
if !rune { RemoveItem(it); }
break;
} elseif it2 == null {
empty = true;
}
}
} whilenot ++i > 5;
if i > 5 {
if bought && !empty {
p = GetOwningPlayer(u);
SetPlayerState(p, PLAYER_STATE_RESOURCE_GOLD, /*
*/ GetPlayerState(p, PLAYER_STATE_RESOURCE_GOLD) + GetGoldCostByIndex(num));
SetPlayerState(p, PLAYER_STATE_RESOURCE_LUMBER, /*
*/ GetPlayerState(p, PLAYER_STATE_RESOURCE_LUMBER) + GetLumberCostByIndex(num));
} elseif empty {
if own {
CallbackArgument = num;
TriggerEvaluate(GetPickupCallbackByIndex(num));
}
if rune || (norm && !own) || (dis && own) {
if !rune { RemoveItem(it); }
it2 = UnitAddItemById(u, itid);
SetItemCharges(it2, j);
SetItemPlayer(it2, p, false);
}
} else {
DropItem(it, num);
}
}
} else {
do {
exitwhen UnitItemInSlot(u, i) == null;
} whilenot ++i > 5;
if i <= 5 {
if own {
CallbackArgument = num;
TriggerEvaluate(GetPickupCallbackByIndex(num));
}
if rune || (norm && !own) || (dis && own) {
if !rune { RemoveItem(it); }
SetItemPlayer(UnitAddItemById(u, itid), p, false);
}
} elseif bought {
p = GetOwningPlayer(u);
SetPlayerState(p, PLAYER_STATE_RESOURCE_GOLD, /*
*/ GetPlayerState(p, PLAYER_STATE_RESOURCE_GOLD) + GetGoldCostByIndex(num));
SetPlayerState(p, PLAYER_STATE_RESOURCE_LUMBER, /*
*/ GetPlayerState(p, PLAYER_STATE_RESOURCE_LUMBER) + GetLumberCostByIndex(num));
} else {
DropItem(it, num);
}
}
Flag = true;
}
return false;
}

private bool DropActions() {
item it = GetManipulatedItem();
int itid = GetItemTypeId(it), num = GetIndexById(itid);
if Flag && num != 0 && (itid == GetNormalByIndex(num) || itid == GetDisabledByIndex(num)) {
if itid == GetNormalByIndex(num) {
CallbackArgument = num;
TriggerEvaluate(GetDropCallbackByIndex(num));
}
DropItem(it, num);
}
return false;
}

callback onInit() {
trigger pick = CreateTrigger(), drop = CreateTrigger();
for (int i = 0) {
TriggerRegisterPlayerUnitEvent(pick, Player(i), EVENT_PLAYER_UNIT_PICKUP_ITEM, null);
TriggerRegisterPlayerUnitEvent(drop, Player(i), EVENT_PLAYER_UNIT_DROP_ITEM, null);
exitwhen i == 15;
i++;
}
TriggerAddCondition(pick, Condition(function PickActions));
TriggerAddCondition(drop, Condition(function DropActions));
}
}[/code]