//По правилам хорошего тона все константы надо выносить в const func:
constant function Trig_Scouch2_Ability takes nothing returns integer
     return 'A02G'
endfunction

constant function Trig_Scouch2_Dummy takes nothing returns integer
     return 'n006'
endfunction

constant function Trig_Scouch2_Item takes nothing returns integer
     return 'I00H'
endfunction

constant function Trig_Scouch2_Range takes nothing returns real
     return 500.
endfunction

constant function Trig_Scouch2_SquareRange takes nothing returns real
     //Range() * Range()
     return 250000.
endfunction

//===========================================================================
function Trig_Scouch2_Conditions takes nothing returns boolean
     return GetSpellAbilityId() == Trig_Scouch2_Ability()
endfunction

function Trig_Scouch2_Actions takes nothing returns nothing
     //Кастер
     local unit u = GetTriggerUnit()
     //Его координаты
     local real x = GetWidgetX(u)
     local real y = GetWidgetY(u)
     //Владелец
     local player p = GetOwningPlayer(u)
     //Юнит для перебора группы
     local unit u2
     //Его координаты
     local real x2
     local real y2
     //Дамми
     local unit dummy

     call GroupEnumUnitsInRange(udg_Group, x, y, Trig_Scouch2_Range(), null)
     loop
         //Цикл, пока в группе есть юниты
         set u2 = FirstOfGroup(udg_Group)
         exitwhen u2 == null
         call GroupRemoveUnit(udg_Group, u2)

         //Задаем координаты
         set x2 = GetWidgetX(u2)
         set y2 = GetWidgetY(u2)
         //Из геометрии - расстояние между точками на плоскости
         if IsUnitEnemy(u2, p) and x2 * x2 + y2 * y2 <= Trig_Scouch2_SquareRange() then
             //Создать дамми смотрящим в сторону цели
             set dummy = CreateUnit(p, Trig_Scouch2_Dummy(), x, y, Atan2(y2 - y, x2 - x))
             //Задать ему время жизни
             call UnitApplyTimedLife(dummy, 'BTLF', 1.)
             //Удалить сразу после смерти
             call SetUnitExploded(dummy, true)
             //Дать предмет и заставить использовать
             call UnitUseItemTarget(dummy, UnitAddItemById(dummy, Trig_Scouch2_Item()), u2)
         endif
     endloop

     set u = null
     set p = null
     set dummy = null
endfunction

//===========================================================================
function InitTrig_Scouch2 takes nothing returns nothing
     local trigger trig = CreateTrigger()
     local integer i = 0
     loop
         call TriggerRegisterPlayerUnitEvent(trig, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
         exitwhen i == 15
         set i = i + 1
     endloop
     call TriggerAddCondition(trig, Condition(function Trig_Scouch2_Conditions))
     call TriggerAddAction(trig, function Trig_Scouch2_Actions)
     set trig = null
endfunction