unit u=...
unit e
group g=CreateGroup()

call GroupEnumUnitsInRange(g,GetUnitX(u),GetUnitY(u),100., функ. условия)
     loop  
         set e=FirstOfGroup(g)
         exitwhen e==null
         ...
         call UnitDamageTarget( u, e, dmgl, true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNKNOWN, WEAPON_TYPE_WHOKNOWS)
         ...
     call GroupRemoveUnit(g,e)
     endloop
.....................
        call DestroyGroup(g)

globals
     constant hashtable Hash = InitHashtable()
     constant group G = CreateGroup()
endglobals

//===========================================================================
globals
     constant integer Fireball_Ability = 'A000'
     constant integer Fireball_Dummy = 'h000'
     constant string Fireball_Effect = ""
     constant string Fireball_Attach = "chest"
     constant real Fireball_Period = .05
endglobals

constant function Fireball_Speed takes integer lvl returns real
     return 800. + 100. * lvl
endfunction

constant function Fireball_Damage takes integer lvl returns real
     return 500.
endfunction

constant function Fireball_Range takes integer lvl returns real
     return 400. + 50. * lvl
endfunction

//===========================================================================
function Trig_Fireball_Conditions takes nothing returns boolean
     return GetSpellAbilityId() == Fireball_Ability
endfunction

function Trig_Fireball_Timer takes nothing returns nothing
     local timer t = GetExpiredTimer()
     local integer id = GetHandleId(t)
     local unit dummy = LoadUnitHandle(Hash, id, 0)
     local player p = GetOwningPlayer(dummy)
     local integer remaining = LoadInteger(Hash, id, 0) - 1
     local integer lvl
     local unit u
     local real dmg
     if remaining <= 0 then
         set lvl = LoadInteger(Hash, id, 1)
         set dmg = Fireball_Damage(lvl)
         call GroupEnumUnitsInRange(G, GetWidgetX(dummy), GetWidgetY(dummy), Fireball_Range(lvl), null)
         loop
             set u = FirstOfGroup(G)
             exitwhen u == null
             call GroupRemoveUnit(G, u)
             if GetWidgetLife(u) > .405 and IsUnitEnemy(u, p) and not IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE) then
                 call DestroyEffect(AddSpecialEffectTarget(Fireball_Effect, u, Fireball_Attach))
                 call UnitDamageTarget(dummy, u, dmg, true, false, ATTACK_TYPE_MAGIC, DAMAGE_TYPE_MAGIC, null)
             endif
         endloop
         call KillUnit(dummy)
         call FlushChildHashtable(Hash, id)
         call PauseTimer(t)
         call DestroyTimer(t)
     else
         call SaveInteger(Hash, id, 0, remaining)
         call SetUnitX(dummy, GetWidgetX(dummy) + LoadReal(Hash, id, 0))
         call SetUnitY(dummy, GetWidgetY(dummy) + LoadReal(Hash, id, 1))
     endif
     set t = null
     set dummy = null
     set p = null
endfunction

function Trig_Fireball_Actions takes nothing returns nothing
     local unit caster = GetTriggerUnit()
     local real x = GetWidgetX(caster)
     local real y = GetWidgetY(caster)
     local real tx = GetSpellTargetX()
     local real ty = GetSpellTargetY()
     local real a = Atan2(ty - y, tx - x)
     local timer t = CreateTimer()
     local integer id = GetHandleId(t)
     local integer lvl = GetUnitAbilityLevel(caster, Fireball_Ability)
     local real speedPerTact = Fireball_Speed(lvl) * Fireball_Period
     call SaveAgentHandle(Hash, id, 0, CreateUnit(GetOwningPlayer(caster), Fireball_Dummy, x, y, a * 57.29578))
     call SaveReal(Hash, id, 0, speedPerTact * Cos(a))
     call SaveReal(Hash, id, 1, speedPerTact * Sin(a))
     call SaveInteger(Hash, id, 0, R2I(SquareRoot((tx - x) * (tx - x) + (ty - y) * (ty - y)) / speedPerTact))
     call SaveInteger(Hash, id, 1, lvl)
     call TimerStart(t, Fireball_Period, true, function Trig_Fireball_Timer)
     set caster = null
     set t = null
endfunction

//===========================================================================
function InitTrig_Fireball takes nothing returns nothing
     local trigger trig = CreateTrigger()
     local integer i = 0
     loop
         call TriggerRegisterPlayerUnitEvent(trig, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
         exitwhen i == 15
         set i = i + 1
     endloop
     call TriggerAddCondition(trig, Condition(function Trig_Fireball_Conditions))
     call TriggerAddAction(trig, function Trig_Fireball_Actions)
     set trig = null
endfunction

function Tree_winds_HurricaneCrug_FilterUnits takes nothing returns boolean
     return GetWidgetLife(GetFilterUnit())>.0 and IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false
endfunction

...
call GroupEnumUnitsInRange(g,GetUnitX(ur),GetUnitY(ur),100.,function Tree_winds_HurricaneCrug_FilterUnits)