function Trig_Number_1_Conditions takes nothing returns boolean
      return GetSpellAbilityId() == 'A000'
endfunction

function Trig_Number_1_Timer takes nothing returns nothing
      local timer t = GetExpiredTimer()
      local integer hid = GetHandleId(t)
      local unit caster = LoadUnitHandle(udg_hash, hid, 0)
      local real d = LoadReal(udg_hash, hid, 1)
      local real z = LoadReal(udg_hash, hid, 2)
      local real angle = LoadReal(udg_hash, hid, 3)
      local real dm = LoadReal(udg_hash, hid, 4)
      local real x = GetWidgetX(caster)
      local real y = GetWidgetY(caster)
      if d <= dm / 2  then
          set x = x + 10. * Cos(angle * bj_DEGTORAD)
          set y = y + 10. * Sin(angle * bj_DEGTORAD)
          set z = z + 25.
          call SetUnitPosition(caster, x, y)
          call SetUnitFlyHeight(caster, z, 0.)
      else
          set x = x + 10. * Cos(angle * bj_DEGTORAD)
          set y = y + 10. * Sin(angle * bj_DEGTORAD)
          set z = z - 25.
          call SetUnitPosition(caster, x, y)
          call SetUnitFlyHeight(caster, z, 0.)
      endif
      call SaveReal(udg_hash, hid, 1, d + 10.)
      call SaveReal(udg_hash, hid, 2, z)
      if z <= 0. then
          call PauseTimer(t)
          call DestroyTimer(t)
          call FlushChildHashtable(udg_hash, hid)
      endif
      set caster = null
      set t = null
endfunction

function Trig_Number_1_Actions takes nothing returns nothing
      local timer t = CreateTimer()
      local integer hid = GetHandleId(t)
      local unit caster = GetTriggerUnit()
      local real x = GetWidgetX(caster)
      local real y = GetWidgetY(caster)
      local real z = 10.
      local real angle = 57.295827 * Atan2(GetSpellTargetY() - y, GetSpellTargetX() - x)
      call SaveUnitHandle(udg_hash, hid, 0, caster)
      call SaveReal(udg_hash, hid, 2, z)
      call SaveReal(udg_hash, hid, 3, angle)
      call SaveReal(udg_hash, hid, 4, SquareRoot((GetSpellTargetX() - GetWidgetX(caster)) * (GetSpellTargetX() - GetWidgetX(caster)) + (GetSpellTargetY() - GetWidgetY(caster)) * (GetSpellTargetY() - GetWidgetY(caster))))
      if UnitAddAbility(caster, 'Amrf') then
          call UnitRemoveAbility(caster, 'Amrf')
      endif
      call TimerStart(t, .01, true, function Trig_Number_1_Timer)
      set caster = null
      set t = null
endfunction

function InitTrig_Number_1 takes nothing returns nothing
      set gg_trg_Number_1 = CreateTrigger()
      call TriggerRegisterAnyUnitEventBJ(gg_trg_Number_1, EVENT_PLAYER_UNIT_SPELL_EFFECT)
      call TriggerAddCondition(gg_trg_Number_1, Condition( function Trig_Number_1_Conditions))
      call TriggerAddAction(gg_trg_Number_1, function Trig_Number_1_Actions)
endfunction