globals
    constant hashtable udg_Hash = InitHashtable()
    constant integer Spell_Rocket_Ability = 'A000'
    constant integer Spell_Rocket_Dummy = 'h000'
    constant real Spell_Rocket_Speed = 20.//speed * period
    constant real Spell_Rocket_Period = .05
    constant real Spell_Rocket_ExplodeRange = 100.
endglobals

constant function Trig_Rocket_Damage takes integer level returns real
    return 50. + level * 100.
endfunction

function Trig_Rocket_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == Spell_Rocket_Ability
endfunction

function Trig_Rocket_Timer takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit r = LoadUnitHandle(udg_Hash, id, 0)
    local unit u2 = LoadUnitHandle(udg_Hash, id, 1)
    local real x = GetWidgetX(r)
    local real y = GetWidgetY(r)
    local real x2 = GetWidgetX(u2)
    local real y2 = GetWidgetY(u2)
    local real a = Atan2(y2 - y, x2 - x)
    if IsUnitInRange(r, u2, Spell_Rocket_ExplodeRange) then
        call UnitDamageTarget(r, u2, LoadReal(udg_Hash, id, 2), true, false, null, DAMAGE_TYPE_MAGIC, null)
        call KillUnit(r)
        //call PauseTimer(t)
        call DestroyTimer(t)
        call FlushChildHashtable(udg_Hash, id)
    else
        call SetUnitFacing(r, a * 57.296)
        call SetUnitX(r, x + Cos(a) * Spell_Rocket_Speed)
        call SetUnitY(r, y + Sin(a) * Spell_Rocket_Speed)
    endif
    set t = null
    set r = null
    set u2 = null
endfunction

function Trig_Rocket_Actions takes nothing returns nothing
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    local unit u = GetTriggerUnit()
    local unit u2 = GetSpellTargetUnit()
    local real x = GetWidgetX(u)
    local real y = GetWidgetY(u)
    call SaveAgentHandle(udg_Hash, id, 0, CreateUnit(GetOwningPlayer(u), Spell_Rocket_Dummy, x, y, Atan2(GetWidgetY(u2) - y, GetWidgetX(u2) - x) * 57.296))
    call SaveAgentHandle(udg_Hash, id, 1, u2)
    call SaveReal(udg_Hash, id, 2, Trig_Rocket_Damage(GetUnitAbilityLevel(u, Spell_Rocket_Ability)))
    call TimerStart(t, Spell_Rocket_Period, true, function Trig_Rocket_Timer)
    set t = null
    set u = null
    set u2 = null
endfunction

function InitTrig_Rocket takes nothing returns nothing
    local trigger trig = CreateTrigger()
    local integer i = 0
    loop
        call TriggerRegisterPlayerUnitEvent(trig, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
        exitwhen i == 11
        set i = i + 1
    endloop
    call TriggerAddCondition(trig, Condition(function Trig_Rocket_Conditions))
    call TriggerAddAction(trig, function Trig_Rocket_Actions)
    set trig = null
endfunction