include "cj_print.j";

library MyMultiboard {
    include "cj_types_priv.j";

    define {
        private TITLE = "Sir Nikolas";
        private ICON_LEVEL = "";
        private ICON_FRAGS = "";
        private ICON_DEATHS = "";
        private ICON_GOLD = "";
        private UPDATE_PERIOD = 1.;
        private NAME_LENGTH = .1;
        private STATE_LENGTH = .015;
        private COLOUR_LEVEL = "|cff0000ff";
        private COLOUR_FRAGS = "|cff00ff00";
        private COLOUR_DEATHS = "|cffff0000";
    }

    private multiboard MB;
    private int row[8], frags[8], deaths[8];

    public void Show(bool flag) {
        MultiboardDisplay(MB, flag);
    }

    public void ShowFor(player p, bool flag) {
        if GetLocalPlayer() == p { Show(flag); }
    }

    public void SetIcon(player p, string path) {
        multiboarditem mbi = MultiboardGetItem(MB, row[GetPlayerId(p)], 0);
        MultiboardSetItemIcon(mbi, path);
        MultiboardReleaseItem(mbi);
    }

    callback onHeroLevel() {
        int i = GetPlayerId(GetOwningPlayer(GetTriggerUnit()));
        if i < 7 {
            multiboarditem mbi = MultiboardGetItem(MB, row[i], 1);
            sMultiboardSetItemValue(mbi, "^s^i", COLOUR_LEVEL, GetHeroLevel(GetTriggerUnit()));
            MultiboardReleaseItem(mbi);
        }
    }

    callback onUnitDeath() {
        unit u = GetTriggerUnit();
        multiboarditem mbi;
        if GetOwningPlayer(u) == Player(7) {
            int i = GetPlayerId(GetOwningPlayer(GetKillingUnit()));
            frags[i]++;
            mbi = MultiboardGetItem(MB, row[i], 2);
            sMultiboardSetItemValue(mbi, "^s^i", COLOUR_FRAGS, frags[i]);
            MultiboardReleaseItem(mbi);
        } elseif IsUnitType(u, UNIT_TYPE_HERO) == true {
            int i = GetPlayerId(GetOwningPlayer(u));
            deaths[i]++;
            mbi = MultiboardGetItem(MB, row[i], 3);
            sMultiboardSetItemValue(mbi, "^s^i", COLOUR_DEATHS, deaths[i]);
            MultiboardReleaseItem(mbi);
        }
    }

    callback onInit() {
        TimerStart(CreateTimer(), .0, false, \
            lambda void() {
                MB = CreateMultiboard();
                int id[ ];
                int count = 1;
                for (int i = 0) {
                    if GetPlayerSlotState(Player(i)) == PLAYER_SLOT_STATE_PLAYING && /*
                    */ GetPlayerController(Player(i)) == MAP_CONTROL_USER {
                        id[count] = i;
                        row[i] = count++;
                    }
                    exitwhen i == 7;
                    i++;
                }
                MultiboardSetColumnCount(MB, 5);
                MultiboardSetRowCount(MB, count);
                MultiboardSetTitleText(MB, TITLE);
                MultiboardSetItemsStyle(MB, true, false);
                multiboarditem mbi;
                for (int j = 0) {
                    real w;
                    mbi = MultiboardGetItem(MB, 0, j);
                    MultiboardSetItemStyle(mbi, true, true);
                    if j < 2 {
                        if j == 0 {
                            w = NAME_LENGTH;
                        } else {
                            MultiboardSetItemIcon(mbi, ICON_LEVEL);
                            w = STATE_LENGTH;
                        }
                    } elseif j == 2 {
                        MultiboardSetItemIcon(mbi, ICON_FRAGS);
                    } elseif j == 3 {
                        MultiboardSetItemIcon(mbi, ICON_DEATHS);
                    } else {
                        MultiboardSetItemIcon(mbi, ICON_GOLD);
                    }
                    MultiboardSetItemWidth(mbi, w);
                    MultiboardReleaseItem(mbi);
                    for (int i = 1) {
                        mbi = MultiboardGetItem(MB, i, j);
                        if j == 0 {
                            sMultiboardSetItemValue(mbi, "^ipc", id[i]);
                            MultiboardSetItemStyle(mbi, true, true);
                        } elseif j == 1 {
                            sMultiboardSetItemValue(mbi, "^s1", COLOUR_LEVEL);
                        } elseif j == 2 {
                            sMultiboardSetItemValue(mbi, "^s0", COLOUR_FRAGS);
                        } elseif j == 3 {
                            sMultiboardSetItemValue(mbi, "^s0", COLOUR_DEATHS);
                        } else {
                            sMultiboardSetItemValue(mbi, "^igold", /*
                            */ GetPlayerState(Player(id[i]), PLAYER_STATE_RESOURCE_GOLD));
                        }
                        MultiboardSetItemWidth(mbi, w);
                        MultiboardReleaseItem(mbi);
                        exitwhen ++i == count;
                    }
                    exitwhen j == 4;
                    j++;
                }
                mbi = MultiboardGetItem(MB, 0, 0);
                MultiboardSetItemStyle(mbi, false, false);
                MultiboardReleaseItem(mbi);
                TimerStart(GetExpiredTimer(), UPDATE_PERIOD, true, \
                    lambda void() {
                        for (int i = 0) {
                            if row[i] != 0 {
                    multiboarditem mbi = MultiboardGetItem(MB, row[i], 4);
                    sMultiboardSetItemValue(mbi, "^igold", /*
                    */ GetPlayerState(Player(i), PLAYER_STATE_RESOURCE_GOLD));
                    MultiboardReleaseItem(mbi);
                            }
                            exitwhen i == 7;
                            i++;
                        }
                    }
                );
                MultiboardDisplay(MB, true);
            }
        );
    }
}