function Agoniya_Damage takes nothing returns nothing
     local integer ID = udg_ID
     local unit uc = LoadUnitHandle( udg_H, ID, 0)
     local unit ut = LoadUnitHandle( udg_H, ID, 1)
     local integer lvl = LoadInteger( udg_H, ID, 2)
     local integer takt = LoadInteger( udg_H, ID, 3)

     // udg_Destroy - приказ убрать бафф, udg_Dispell - кто-то снял ( должены быть у всех баффов)
     if udg_Destroy or udg_Dispell then
         call UnitRemoveAbility( ut, 'Buhf')
     else
         set udg_MissB = false //шанса на промаха не будет
         // UnitDamageMagic - нанести магический урон
         // uc - кастер, ut - цель, урон, 3 - тип урона(темная магия), 16.6 - 16.6% дополнительного урона от магии, например
         // у героя доп. урон 180, значит добавляется 30 на каждом такте,
         //true - при получении урона запустить функцию( возможен крит, сопротивление и.т.д и события)
         call UnitDamageMagic( uc, ut, I2R(lvl*10*takt), 3, 16.6, true)
         if takt != 6 then
             call SaveInteger( udg_H, ID, 3, takt+1)
         else
             // RemoveEvent - убирает событие или бафф
             // ut - с кого, ID - номер в хэш, false - не запускать функцию ("Agoniya_Damage")
             call RemoveEvent( ut, ID, false)
         endif
     endif

     set uc = null
     set ut = null
endfunction

function Agoniya_Actions takes nothing returns nothing
     local unit u = GetTriggerUnit()
     local unit ut = GetSpellTargetUnit()
     local integer ID

     //BuffMiss - дает возможность, что у цели будет сопротивление или у кастующего промах. Если был промах или
     // сопротивление, то функция возвращает false (только магические баффы)
     // u - кастующий, ut - цель, 3 - тип магического урона(темная магия),  
     //'Buhf' - снять этот бафф в случае промаха или сопротивления
     if not BuffMiss( u, ut, 3, 'Buhf') then
         //AddBuff - создать бафф на юните, возвращает число для хэш куда записывать данные
         //ut - на ком, 0 - уникальный номер (если будет наложен еще 1 бафф, то снять этот),  
         //"Agoniya_Damage" - выполняемая функция, 6 - тип баффа(проклятие), 3 - запускать функцию каждые 3 секнуды,
         //true - запускать функцию больше 1 раза, true - снять при смерти героя (запустится ф-ция "Agoniya_Damage", а
         // udg_Destroy будет = true)
         set ID = AddBuff( ut, 0, "Agoniya_Damage", 6, 3, true, true)
         call SaveUnitHandle( udg_H, ID, 0, u)
         call SaveUnitHandle( udg_H, ID, 1, ut)
         call SaveInteger( udg_H, ID, 2, GetUnitAbilityLevel( u, 'A003'))
         call SaveInteger( udg_H, ID, 3, 1)
     endif

     set u = null
     set ut = null
endfunction

function InitTrig_Agoniya takes nothing returns nothing
endfunction

function Frost_Arrow_Buff takes nothing returns nothing
     if udg_Destroy or udg_Dispell then
         call UnitRemoveAbility( LoadUnitHandle( udg_H, udg_ID, 0), 'Bslo')
     else
         //действие закончилось, необходимо убрать бафф
         call RemoveEvent( LoadUnitHandle( udg_H, udg_ID, 0), udg_ID, false)
     endif
endfunction

function Frost_Arrow_Damage takes nothing returns nothing
     local integer ID = udg_ID
     local unit u = LoadUnitHandle( udg_H, ID, 0)
     local unit ut = LoadUnitHandle( udg_H, ID, 1)
     local real lvl = LoadReal( udg_H, ID, 3)

     //если дамми достиг цели
     if not udg_Destroy then
         call UnitDamageMagic( u, ut, GetRandomReal(lvl*25., lvl*50.), 0, 100., true)

         //урон был нанесен
         if udg_NoDamage == 0 and GetUnitState( ut, UNIT_STATE_LIFE) > 0. then
             call SaveUnitHandle( udg_H, AddBuff( ut, 1, "Frost_Arrow_Buff", 1, 3, false, true), 0, ut)

             //CreateDummyCaster - создет дамми кастера, для одноразового использования спелла
             //GetOwningPlayer(u) - чей, GetUnitX(ut) - X точки где создавать дамми, GetUnitY(ut) - Y точки где создавать дамми
             //ut - цель, 'A005' - спелл, 1 - уровень спелла, "slow" - приказ, 1. - время жизни дамми
             call CreateDummyCaster( GetOwningPlayer(u), GetUnitX(ut), GetUnitY(ut), ut, 'A005', 1, "slow", 1.)
         endif
     endif

     call RemoveUnit(LoadUnitHandle( udg_H, ID, 2))
     call FlushChildHashtable( udg_H, ID)

     set u = null
     set ut = null
endfunction

function Frost_Arrow_Actions takes nothing returns nothing
     local unit u = LoadUnitHandle( udg_H, udg_ID, 10)
     local unit ut = LoadUnitHandle( udg_H, udg_ID, 11)
     local unit d = CreateUnit( GetOwningPlayer(u), 'e001', GetUnitX(u), GetUnitY(u), bj_RADTODEG * AngleBetweenUnits( u, ut))
     local real lvl = LoadReal( udg_H, udg_ID, 12)
     //AddEventDummySpell - двигает дамми к цели, возвращает число для хэш куда записывать данные
     // u - кто кастовал, d - дамми, ut - цель, 0. - X конечной точки, 0. - Y конечной точки(если ut != null, то
     // неавжно какие x и y),
     //  6. - на сколько передвигать, .01 - таймер, false - не удалять при смерти кастера,
     //  true -  убрать при смерти цели, "Frost_Arrow_Damage" - функция по достижении цели
     local integer ID = AddEventDummySpell( u, d, ut, 0., 0., 6., .01, false, true, "Frost_Arrow_Damage")

     call SaveUnitHandle( udg_H, ID, 0, u)
     call SaveUnitHandle( udg_H, ID, 1, ut)
     call SaveUnitHandle( udg_H, ID, 2, d)
     call SaveReal( udg_H, ID, 3, lvl)

     set u = null
     set ut = null
     set d = null
endfunction

function InitTrig_Frost_Arrow takes nothing returns nothing
endfunction

function Antimagic_Barrier_Buff takes nothing returns nothing
     local integer ID = udg_ID
     local unit u = LoadUnitHandle( udg_H, ID, 0)

     if udg_Destroy or udg_Dispell then
         call UnitRemoveAbility( u, 'Bhaf')
     else
         call RemoveEvent( u, LoadInteger( udg_H, ID, 1), false)
         call RemoveEvent( u, ID, false)
     endif

     set u = null
endfunction

function Antimagic_Barrier_Damage takes nothing returns nothing
     //увеличить шанс на промах на 60%
     set udg_Miss = udg_Miss + 60.
     //уменьшить весь урон в 2 раза
     set udg_Damage_Full = udg_Damage_Full*.5
endfunction

function Antimagic_Barrier_Actions takes nothing returns nothing
     local unit u = GetTriggerUnit()
     local integer IDbuff = AddBuff( u, 3, "Antimagic_Barrier_Buff", 2, 10., false, true)
     //AddEventUnitGetDamage_Attack - добавить событие юнит нанес/получил урон, возвращает число для хэш
     //куда записывать данные
     // u - на ком событие, 4 - уникальный номер, "Antimagic_Barrier_Damage" - выполняемая функция, false - получил урон,
     // true - до нанесения урона, false - не ближний физический, false - не дальний физический,
     // false - не физический( от способностей), true - магический, false - не кровотечение, false - не яд, true - крит,
     // false - не уклонение, false - не сопротивление, false - не парирование, false - не блок, true - обычный урон
     // 0. - без таймера, false - не убирать при смерти героя( снимается через бафф)
     local integer IDevent = AddEventUnitGetDamage_Attack( u, 4, "Antimagic_Barrier_Damage", false, true, false, false, false, true, false, false, true, false, false, false, false, false, true, 0., false)

     call SaveUnitHandle( udg_H, IDbuff, 0, u)
     call SaveInteger( udg_H, IDbuff, 1, IDevent)

     set u = null
endfunction

function InitTrig_Antimagic_Barrier takes nothing returns nothing
endfunction