library_once HandleData {
      private int Storage[16383];

      void SetHandleData(handle h, int data) {
          Storage[GetHandleId(h) - 0x100000] = data;
      }

      int GetHandleData(handle h) {
          return Storage[GetHandleId(h) - 0x100000];
      }
}

library_once G { constant group G = CreateGroup(); }

library Vacuum requires HandleData {
      define {
          private SPELL = 'A000';
          private RANGE(lvl) = (200. + 50. * (lvl));
          private TIME(lvl) = 2.;
          private DAMAGE(lvl) = (100. + 150. * (lvl));
          private PERIOD = .05;
      }

      private struct Vacuum {
          timer t = CreateTimer();
          unit u, caster;
          real initialX, initialY;
          real dx, dy;
          real time;
          real damage;
      }

      private void onTimer() {
          Vacuum v = GetHandleData(GetExpiredTimer());
          v.time -= PERIOD;
          if v.time > .0 {
              SetUnitX(v.u, GetWidgetX(v.u) + v.dx);
              SetUnitY(v.u, GetWidgetY(v.u) + v.dy);
          } else {
              SetUnitX(v.u, v.initialX);
              SetUnitY(v.u, v.initialY);
              UnitDamageTarget(v.caster, v.u, v.damage, true, false, null, null, null);
              PauseTimer(v.t);
              DestroyTimer(v.t);
              v.destroy();
          }
      }

      callback onUnitSpellEffect(SPELL) {
          unit caster = GetTriggerUnit();
          player p = GetOwningPlayer(caster);
          int lvl = GetUnitAbilityLevel(caster, SPELL);
          real x = GetSpellTargetX(), y = GetSpellTargetY();
          for (unit u; UnitsInRange(x, y, RANGE(lvl)) use G) {
              if GetWidgetLife(u) > .405 && IsUnitEnemy(u, p) && !IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE) {
                  Vacuum v = Vacuum.create();
                  v.u = u;
                  v.caster = caster;
                  v.initialX = GetWidgetX(u);
                  v.initialY = GetWidgetY(u);
                  real a = x - v.initialX, b = y - v.initialY;
                  real speed = SquareRoot(a * a + b * b) / TIME(lvl);
                  a = Atan2(b, a);
                  v.dx = speed * Cos(a);
                  v.dy = speed * Sin(a);
                  v.time = TIME(lvl);
                  v.damage = DAMAGE(lvl);
                  SetHandleData(v.t, v);
                  TimerStart(v.t, PERIOD, true, function onTimer);
              }
          }
      }
}